Tweak Junk Email Reporting tool to default to particular email on send?

[Geldner]

I have the Junk Reporting tool installed on Outlook 2019 64-bit. It works fine via the registry hack to always send to Microsoft AND to SPAMCOP reporting. However, I'd rather have the tool SEND via my GMAIL account and not my default hosted account. (The hosted account usually flags the outbound reporting email as SPAM and rejects it.) Is there a way of doing this in post processing? IOW, the logic would be if TO: contains @spamcop.net then SEND from my Gmail account. Or maybe there's a further registry hack to default the Junk Tool to a particular FROM address. (Microsoft doesn't really support the tool these days).

 

[Diane Poremsky]

if you don't need to send to Microsoft and only want to send to spamcop, I have a macro here somewhere that will get the message header, add it to the message and send. It can set the from account before sending.

Ah, found it.

Get Outlook's Internet Headers using VBA

Use this code sample and function to display the Internet header of selected message in a new message form.

www.slipstick.com

 

[Geldner]

Thanks Diane. With some cut & paste and fooling around, I was able to make it work. Certainly a lot easier to report to SpamCop only. Note that the SPAM report macro does not have a way of setting the outbound email account for sending. So I cobbled this together. If you see an easier way to do it, let me know. I left the display vs send alone and took out the boilerplate note since SpamCop no likey that stuff.

Sub ForwardSpam()
      Dim olItem As Outlook.MailItem, olMsg As Outlook.MailItem
      Dim strHeader As String
      Dim strFWHeader As String
      Dim oAccount As Outlook.Account
      
      For Each olItem In Application.ActiveExplorer.Selection
          strHeader = GetInetHeaders(olItem)
          For Each oAccount In Application.Session.Accounts
              If oAccount = "<sending account name>" Then
              Set olMsg = olItem.Forward
              With olMsg
                  .To = "<SPAM reporting address>"
                  .BodyFormat = olFormatPlain
                  .Body = strHeader & vbCrLf & vbCrLf & olItem.Body
                  .SendUsingAccount = oAccount
              .Display ' change to .send when satisfied
         End With
         End If
      Next
      olItem.Delete
    Next
      Set olMsg = Nothing
  End Sub
 
  Function GetInetHeaders(olkMsg As Outlook.MailItem) As String
      ' Purpose: Returns the internet headers of a message.'
      ' Written: 4/28/2009'
      ' Author:  BlueDevilFan'
      ' //techniclee.wordpress.com/
      ' Outlook: 2007'
      Const PR_TRANSPORT_MESSAGE_HEADERS = "http://schemas.microsoft.com/mapi/proptag/0x007D001E"
      Dim olkPA As Outlook.PropertyAccessor
      Set olkPA = olkMsg.PropertyAccessor
      GetInetHeaders = olkPA.GetProperty(PR_TRANSPORT_MESSAGE_HEADERS)
      Set olkPA = Nothing
  End Function

 

[Diane Poremsky]

It looks good.

This is correct to set the sending account -

For Each oAccount In Application.Session.Accounts
If oAccount = "<sending account name>" Then
Set olMsg = olItem.Forward