Macro to move mail from Inbox if older than 4 days

[jo15765]

I would like a macro that I can add to the Windows Scheduler that will run every day and it will move mail older than 4 days from my inbox into a personal folder in my inbox...if that makes sense.

 

[Diane Poremsky]

Tested this in outlook 2010 - moving mail 7 days old. It would need tweaked to run outside of outlook and it may trigger the security prompts. Could convert it to application_startup so it runs everytime outlook runs or run it from a command button.

Sub MoveMail()
   ' Declare all variables.
   Dim objOutlook As Outlook.Application
   Dim objNamespace As Outlook.NameSpace
   Dim objSourceFolder As Outlook.MAPIFolder
   Dim objDestFolder As Outlook.MAPIFolder
   Dim objVariant As Variant
   Dim lngMovedMailItems As Long
   Dim intCount As Integer
   Dim intDateDiff As Integer
   Dim strDestFolder As String
 
   Set objOutlook = Application
   Set objNamespace = objOutlook.GetNamespace("MAPI")
   Set objSourceFolder = objNamespace.GetDefaultFolder(olFolderInbox)
 
   For intCount = objSourceFolder.Items.Count To 1 Step -1
       Set objVariant = objSourceFolder.Items.Item(intCount)
       DoEvents
       If objVariant.Class = olMail Then
         
            intDateDiff = DateDiff("d", objVariant.SentOn, Now)
          
           If intDateDiff > 7 Then
         
           'use datafile name and each folder in the path - outlook 2010 uses the email address as the pst or mailbox  name
               Set objDestFolder = objNamespace.Folders("[EMAIL="diane@domain.com").Folders("Inbox").Folders("Old"]diane@domain.com").Folders("Inbox").Folders("Old[/EMAIL]")
             objVariant.Move objDestFolder
           
             'count the # of items moved
              lngMovedMailItems = lngMovedMailItems + 1
               Set objDestFolder = Nothing
           End If
       End If
   Next
 
   ' Display the number of items that were moved.
   MsgBox "Moved " & lngMovedMailItems & " messages(s)." 
 
End Sub

 

[Diane Poremsky]

BTW, you could do this using Autoarchive. It will move it to a folder in an archive pst file not in your mailbox, but no coding and little configuration needed to use it.

 

[jo15765]

I am assuming I would just add this code to the VBE just like I would in Access or Excel?

How would I use auto-archiving?

 

[Diane Poremsky]

Yes, add it to ThisOutlookSession just like Access or Excel.

AutoArchiving: Go to Tools, Accounts, Other, Archiving to enable. Set it to run every day or every xx days. You can set a default for all folders - but unless you explicitly enable a folder for AutoArchive or pressed the button to Apply the setting to all folders, only the folders you configure using Properties, AutoArchive will be processed when AutoArchive runs.

Then right click on the Inbox and choose Properties, then AutoArchiving tab and set a different value.

We have some info at Outlook's AutoArchive Feature on using autoarchive to clean out junk and deleted mail - basics are the same, but you'll move rather than delete.