VBA to copy sent items to folder

[Joseph Cooper]

One of our users has a script set up which pops up with a folder view when "Send" is clicked. This allows the sent email to be put in to a folder they choose.

The issue is, that they want the email to still go into "Sent Items" as well as their chosen folder.

Private Sub Application_ItemSend(ByVal Item As Object, _ 
                                 Cancel As Boolean) 
    Dim objNS As NameSpace 
    Dim objFolder As MAPIFolder 
    On Error Resume Next 
    Set objNS = Application.Session 
    If Item.Class = olMail Then 
        Set objFolder = objNS.PickFolder 
        If Not objFolder Is Nothing And _ 
          IsInDefaultStore(objFolder) And _ 
          objFolder.DefaultItemType = olMailItem Then 
            Set Item.SaveSentMessageFolder = objFolder 
        Else 
            Set objFolder = _ 
              objNS.GetDefaultFolder(olFolderSentMail) 
            Set Item.SaveSentMessageFolder = objFolder 
        End If 
    End If 
    Set objFolder = Nothing 
    Set objNS = Nothing 
End Sub 
Public Function IsInDefaultStore(objOL As Object) As Boolean 
    Dim objApp As Outlook.Application 
    Dim objNS As Outlook.NameSpace 
    Dim objInbox As Outlook.MAPIFolder 
    Dim blnBadObject As Boolean 
    On Error Resume Next 
    Set objApp = objOL.Application 
    If Err = 0 Then 
        Set objNS = objApp.Session 
        Set objInbox = objNS.GetDefaultFolder(olFolderInbox) 
        Select Case objOL.Class 
            Case olFolder 
                If objOL.StoreID = objInbox.StoreID Then 
                    IsInDefaultStore = True 
                Else 
                    IsInDefaultStore = False 
                End If 
            Case olAppointment, olContact, olDistributionList, _ 
                 olJournal, olMail, olNote, olPost, olTask 
                If objOL.Parent.StoreID = objInbox.StoreID Then 
                    IsInDefaultStore = True 
                Else 
                    IsInDefaultStore = False 
                End If 
            Case Else 
                blnBadObject = True 
        End Select 
    Else 
        blnBadObject = True 
    End If 
    If blnBadObject Then 
        MsgBox "This function isn't designed to work " & _ 
                "with " & TypeName(objOL) & _ 
                " objects and will return False.", _ 
                , "IsInDefaultStore" 
        IsInDefaultStore = False 
    End If 
    Set objApp = Nothing 
    Set objNS = Nothing 
    Set objInbox = Nothing 
End Function

 

[Joseph Cooper]

I added this:

Set msg = Item.Copy 
msg.Move objNS.GetDefaultFolder(olFolderSentMail)

Which worked. but it doesn't save any date information at all. it saves a copy, but the date in "sent items" comes up as "None". and the email is displayed as unread.

 

[Joseph Cooper]

Fixed this by setting up a rule & alert to copy all sent emails to a folder.

Thanks for your help guys.

 

[Forum Admin]

Try saving it twice - not sure it will work, but it would be the easiest way to address it.
Set Item.SaveSentMessageFolder = objFolder
Set Item.SaveSentMessageFolder =objNS.GetDefaultFolder(olFolderSentMail)

Nevermind Bad logic on that one.