VBA Only works once then doesn't work

[OakwoodBespoke]

Operating system::    Windows 11
Outlook version:     Office 365
Email type or host:    IMAP

---

Hi

I have found a VBA on another forum to reply to all in an email with attachments.
The fist time it worked perfectly, now it doesn't work, i tried on a different machine and it does the same.

I get the attached error

I'm guessing its something to do with trust centre but if have tried allowing all macros but still doesnt work

Your help with this would be much appreciated

Here is the code

Sub ReplyWithAttachments()
Dim oReply As Outlook.MailItem
Dim oItem As Object

Set oItem = GetCurrentItem()
If Not oItem Is Nothing Then
Set oReply = oItem.Reply
CopyAttachments oItem, oReply
oReply.Display
oItem.UnRead = False
End If

Set oReply = Nothing
Set oItem = Nothing
End Sub

Sub ReplyAllWithAttachments()
Dim oReply As Outlook.MailItem
Dim oItem As Object

Set oItem = GetCurrentItem()
If Not oItem Is Nothing Then
Set oReply = oItem.ReplyAll
CopyAttachments oItem, oReply
oReply.Display
oItem.UnRead = False
End If

Set oReply = Nothing
Set oItem = Nothing
End Sub
Function GetCurrentItem() As Object
Dim objApp As Outlook.Application

Set objApp = Application
On Error Resume Next
Select Case TypeName(objApp.ActiveWindow)
Case "Explorer"
Set GetCurrentItem = objApp.ActiveExplorer.Selection.Item(1)
Case "Inspector"
Set GetCurrentItem = objApp.ActiveInspector.CurrentItem
End Select

Set objApp = Nothing
End Function

Sub CopyAttachments(objSourceItem, objTargetItem)
Set fso = CreateObject("Scripting.FileSystemObject")
Set fldTemp = fso.GetSpecialFolder(2) ' TemporaryFolder
strPath = fldTemp.Path & "\"
For Each objAtt In objSourceItem.Attachments
strFile = strPath & objAtt.FileName
objAtt.SaveAsFile strFile
objTargetItem.Attachments.Add strFile, , , objAtt.DisplayName
fso.DeleteFile strFile
Next

Set fldTemp = Nothing
Set fso = Nothing
End Sub

 

[Diane Poremsky]

Did you change the trust center settings then restart Outlook?

You need to have macro security set to the lowest setting during testing: Enable all macros. The macros will not work with the top two options that disable all macros or unsigned macros. You could choose the option Notification for all macros, then accept it each time you restart Outlook, however, because it's hard to sneak macros into Outlook (unlike in Word and Excel), allowing all macros is safe, especially during the testing phase. You can sign the macro when it is finished and change the macro security to notify.

To check your macro security, look in File > Options > Trust Center > Trust Center Settings. Change the Macro Settings.

How to use Outlook's VBA Editor

Basic instructions on using Outlook's VBA editor: how to open it, where to put the code, how to sign your code.

www.slipstick.com