Default shape via VBA

[eduperosa]

I sent emails very often with images/screenshots where I want to mark something with a shape or arrow. The default rectangle shape of outlook is like this:

I would like to have a macro, assigned to keyboard shortcut, that formats the shape to something near this (provided that shape is selected):

I know there is the menu when you right-click the shape "Set as default shape", but once a new message is created the chosen default shape is lost.

Thank you all!

 

[Diane Poremsky]

That would use word vba code - I don't have any code handy that does it, but there should be some code sample floating around the internet that does it in word - making it work in Outlook won't be difficult. Actually, you could probably record a macro doing it in word... (not all commands can be recorded).

I think you would need to select the image then run the macro to format it - not select a shape. so the macro will be hard coded to use the size of the image.

 

[eduperosa]

Found the solution:

Public Sub addShape()
Dim oShp As Word.Shape
Dim oSel As Word.Selection
Dim oWrd As Word.Application

Set oWrd = Application.ActiveInspector.WordEditor.Application
Set oSel = oWrd.Selection
Set oShp = oWrd.ActiveDocument.Shapes.addShape(msoShapeRectangle, getXCoord(oSel), getYCoord(oSel), 50, 25)

With oShp
.Fill.Visible = False
.Line.Visible = True
.Line.ForeColor.RGB = RGB(0, 176, 80)
.Line.Weight = 2.25
End With

Set oShp = Nothing
Set oSel = Nothing
Set oWrd = Nothing
End Sub

Private Function getXCoord(ByVal oSel As Word.Selection) As Double
getXCoord = oSel.Range.Information(wdHorizontalPositionRelativeToPage)

End Function

Private Function getYCoord(ByVal oSel As Word.Selection) As Double
getYCoord = oSel.Range.Information(wdVerticalPositionRelativeToPage)
End Function

References that I added to make it work:

Microsoft Scripting Runtime
Microsof Word 16.0 Object Library

 

[Diane Poremsky]

Perfect. It's pretty easy to convert word macros to work on email - DIM and Set the word objects and the necessary references.

It doesn't look like you are using the scripting runtime... does it work without that set.

 

[eduperosa]

You are right , just the Microsof Word 16.0 Object Library does the trick. At the end I added a button on the ribbon to run this macro.