print-list-of-outlook-folders with sort posibility

[Witzker]

Hi Diane
I found your great macro to printout the folder structure of OL

Print a list of your Outlook folders (slipstick.com)

As I have 3 synct outlooks (SimpleSysn) and the tool is really good as time goes by with some errors shutdowns etc. there are sometimes a lot of duplicates in the different outlooks.

To go quickly through the different Ols your tool is very helpful.

BUT if it would be possible to sort the output of the folder list like it is displayed in OL It would be super PERFECT!

How is it possible to sort the output?

Top folder
Topfolder/- Axxxx
Topfolder/- Bxxxx
Topfolder/ Axxxx
Topfolder/ Bxxxx
Topfolder/ Bxxxx / -Axxx
Topfolder/ Bxxxx / Axxx
and so on

I use "-" before the NAME to get important Folders to be listed before the others beginning with A in alphabetic order as Outlook sorts the folders.

I hope you can have a look at the macro and help me.

Public strFolders As String
 
Public Sub GetFolderNames()
    Dim olApp As Outlook.Application
    Dim olSession As Outlook.NameSpace
    Dim olStartFolder As Outlook.MAPIFolder
    Dim lCountOfFound As Long
 
    lCountOfFound = 0
      
    Set olApp = New Outlook.Application
    Set olSession = olApp.GetNamespace("MAPI")
      
     ' Allow the user to pick the folder in which to start the search.
    Set olStartFolder = olSession.PickFolder
      
     ' Check to make sure user didn't cancel PickFolder dialog.
    If Not (olStartFolder Is Nothing) Then
         ' Start the search process.
        ProcessFolder olStartFolder
    End If
    
' Create a new mail message with the folder list inserted
Set ListFolders = Application.CreateItem(olMailItem)
  ListFolders.Body = strFolders
  ListFolders.Display
      
' clear the string so you can run it on another folder
  strFolders = ""
End Sub
 
Sub ProcessFolder(CurrentFolder As Outlook.MAPIFolder)
        
    Dim i As Long
    Dim olNewFolder As Outlook.MAPIFolder
    Dim olTempFolder As Outlook.MAPIFolder
    Dim olTempFolderPath As String
     ' Loop through the items in the current folder.
    For i = CurrentFolder.Folders.Count To 1 Step -1
          
        Set olTempFolder = CurrentFolder.Folders(i)
          
        olTempFolderPath = olTempFolder.FolderPath

     ' Get the count of items in the folder
         olCount = olTempFolder.Items.Count

     'prints the folder path and name in the VB Editor's Immediate window
         Debug.Print olTempFolderPath & " " & olCount
          
        ' prints the folder name only
         ' Debug.Print olTempFolder
          
         ' create a string with the folder names.
         ' use olTempFolder if you want foldernames only
         strFolders = strFolders & vbCrLf & olTempFolderPath & " " & olCount
        
        lCountOfFound = lCountOfFound + 1
          
    Next
     ' Loop through and search each subfolder of the current folder.
    For Each olNewFolder In CurrentFolder.Folders
          
         'Don't need to process the Deleted Items folder
        If olNewFolder.Name <> "Deleted Items" Then
            ProcessFolder olNewFolder
        End If
          
    Next
      
End Sub

 

[Diane Poremsky]

Sorting it after its written would be easier - its difficult for the macro to sort.

 

[Witzker]

Is there a possibility ?

 

[Diane Poremsky]

You need to add the folder names to an array then sort the array. There are some for Excel and Word that could be tweaked. Or you could write it to an excel file (or copy and paste from the list in outlook) then sort using excel features. This would be easier if you wanted to do it all with VBA.

 

[Witzker]

Or you could write it to an excel file (or copy and paste from the list in outlook) then sort using excel features. This would be easier if you wanted to do it all with VBA.

That's it !
You are right THX
---------------------------------
How to set status to solved ??

 

[Diane Poremsky]

Use this in place of the code that save the Outlook message (or in addition to ) - it writes it to a CSV - open in Excel and use Text to columns to separate the message count from the folder name.

If you use tab instead of space (or remove the item count), spaces in folder names won't be a problem when you use text to columns in Excel - this is the processfolder sub:
' create a string with the folder names.
' use olTempFolder if you want foldernames only
strFolders = strFolders & vbCrLf & olTempFolderPath & vbTab & olCount

strPath = Environ("USERPROFILE") & "\Documents\OutlookFolders.csv"
  Debug.Print strPath
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set Fileout = fso.CreateTextFile(strPath, True, False)
    Fileout.WriteLine strFolders

 

[Witzker]

THX
in the meantime I found This:

Option Explicit

Dim excApp As Object, _
         excWkb As Object, _
         excWks As Object, _
         lngRow As Long

Sub EnumerateFolders()
    Dim olkSto As Outlook.Store
    Set excApp = CreateObject("Excel.Application")
    Set excWkb = excApp.Workbooks.Add
    Set excWks = excWkb.Worksheets(1)
    With excWks
        .Cells(1, 1) = "Path"
        .Cells(1, 2) = "Folder"
    End With
    lngRow = 2
    For Each olkSto In Session.Stores
        ProcessFolder olkSto.GetRootFolder
    Next
    excWks.Columns("A:B").AutoFit
    excApp.Visible = True
    Set excWks = Nothing
    Set excWkb = Nothing
    Set excApp = Nothing
    Set olkSto = Nothing
End Sub

Sub ProcessFolder(olkFol As Outlook.Folder)
    Dim olkSub As Outlook.Folder
    excWks.Cells(lngRow, 1) = olkFol.FolderPath
    excWks.Cells(lngRow, 2) = olkFol.Name
    lngRow = lngRow + 1
    For Each olkSub In olkFol.Folders
        ProcessFolder olkSub
    Next
    Set olkSub = Nothing
End Sub

Puts the list directly in an *XLS File
BUT NO Chooser which yours have

And Mainly! The items in Folder are not shown in the list!!

Maybe you could be so kind and edit Your macro (READY to USE) with chooser and Items per folder to write directly to XLS File?
(as I noticed many views on this thread & you can update this on Your Page)
What do you think?
THX in advance!

 

[Diane Poremsky]

I edited the macro here - Print a list of your Outlook folders (slipstick.com) - to save to CSV. It brings up the Outlook folder picker

>> The items in Folder are not shown in the list!!
As in the emails in the folders? I should have a macro for that, somewhere.