VB Script to Delete all contacts under local contacts folder

[fourthgen]

Hi,

I am trying to create a VBScript to delete all the contacts under the local conatcts folder.

I currently have:

Sub DeleteContacts()

Dim myOutlook As Outlook.Application

Dim myInformation As NameSpace

Dim myContacts As Items

Dim myItems As ContactItem

Set myOutlook = CreateObject("Outlook.Apllication")

Set myInformation = myOutlook.GetNameSpace("MAPI")

Set myContacts = myInformation.GetDefaultFolder(olFolderContacts).Items

For Each myItems In myContacts

myItems.Delete

Next

End Sub

This however only deleted everyother contact, so only deletes half at a time. Is there something that I have done wrong and need to change? or is there an easier way to do this using VBScript?

Thank you in advance

 

[Diane Poremsky]

You need to step backwards -

for example, you use your method when you have 3 contacts. When you delete #1, the contact that was #2 becomes #1 but Outlook deletes the current #2, leaving the old #2 (now #1) behind. If you go backwards, the index doesn't change as you delete.

something like this should work -

Dim i As Long

Dim lngCount As Long

lngCount = myItems.count

For i = lngCount To 1 Step -1
myItems(i).Delete
Next

 

[fourthgen]

Thank you for your response,

I have tried the script that you kindly supplied, however, I am getting an error on the

IngCount = myItems.count

Line. It sems to not recognise the .count command? Do you have any further ideas?

Regards

You need to step backwards -

for example, you use your method when you have 3 contacts. When you delete #1, the contact that was #2 becomes #1 but Outlook deletes the current #2, leaving the old #2 (now #1) behind. If you go backwards, the index doesn't change as you delete.

something like this should work -

Dim i As Long

Dim lngCount As Long

lngCount = myItems.count

For i = lngCount To 1 Step -1
myItems(i).Delete
Next

 

[Diane Poremsky]

You don't need myitems in this because mycontacts is the items in the folder.

Sub DeleteContacts()
Dim myOutlook As Outlook.Application
Dim myInformation As NameSpace
Dim myContacts As Items
Dim i As Long
Dim lngCount As Long
Set myOutlook = CreateObject("Outlook.Application")
Set myInformation = myOutlook.GetNamespace("MAPI")
Set myContacts = myInformation.GetDefaultFolder(olFolderContacts).Items
lngCount = myContacts.Count
For i = lngCount To 1 Step -1
myContacts(i).Delete
Next
End Sub