Capture email addresses and create a comma separated list

[leeford]

Hello,

I'm not all that great at creating a script from scratch but have been pretty good at modifying one to meet my needs when I find a similar example.
I'm trying to find a way to capture all the email addresses that are in all of the email address fields of a mail item that I have open, then output only the email addresses in a comma separated list. It could be to the console as dialogue box with content or it could be exported as a csv.

This seems like it would be an easy task, but again, I'm not all that great at creating something from scratch. Programming is not my area of expertise.

Any chance someone would be able to give me an example of a way I could do this?

Thanks in advance,
Lee

 

[Diane Poremsky]

This one shows how to get the addresses - it does it on sent messages, but you only need the "meat" in the middle.

Replace Display Names with Email Addresses

Use an ItemSend macro in Outlook to replace display names on messages with the email address as the message is sent.

www.slipstick.com

not tested, but this should work as long as I did not make a typo.

Dim Recipients As Outlook.Recipients
Dim R As Outlook.Recipient
Dim strR as string

Set Recipients = Item.Recipients
For i = Recipients.count To 1 Step -1

Set R = Recipients.Item(i)

strR = R & "; " & strR

next i

'do whatever 
msgbox strR
debug.print strR

This shows how to run a macro on selected messages or all messages in a folder

Working with All Items in a Folder or Selected Items

These samples contains the basic code for working with all items in a selected folder or selected items in a folder.

www.slipstick.com

 

[Diane Poremsky]

Couldn't resist testing it - you need to use .Address - otherwise you get the display name. And you won't get the sender... unless you add the senderemailaddress field.

If "do whatever" is inside the next block, it will do it after each message - if its after the next block, it will keep adding addresses to the string.

Because this is all within the With obj code in my selected messages sample, you don't need the obj name name, just the . and field name,

      Set R = Recipients.Item(i)
       Debug.Print R.Address
      strR = R.Address & "; " & strR

        Next i

   strR = .SenderEmailAddress & "; " & strR
     
     End With

 

[leeford]

Thank you. I was able to get pretty far and was able to get some output to the message box that I could then copy out, but I didn't get the email addresses, I got what looked like exchange folder locations, instead. What did I do wrong? It looks like I need to get the exchange user now, but I keep running into a lot of different errors when I am trying to get the exchange user.

This is what I got written so far, but it returns the exchange user object, I think. How do I get the email address from that?

Sub GetALLEmailAddresses()

Dim Item As Outlook.MailItem
Dim Recipients As Outlook.Recipients
Dim R As Outlook.Recipient
Dim strR As String

Set Item = Application.ActiveInspector.CurrentItem


Set Recipients = Item.Recipients
With Recipients
    For i = Recipients.Count To 1 Step -1
      Set R = Recipients.Item(i)
       Debug.Print R.Address
       strR = R.Address & "; " & strR

    Next i

   strR = strR & "; " & Item.SenderEmailAddress
  
End With
'do whatever
If MsgBox(strR, vbInformation, "Email Addresses") = vbOK Then
Cancel = True
End If
Debug.Print strR
End Sub

 

[leeford]

I finally got it. Had to do a little more googling, but I found and modified something that works. I have zero error handling, so hopefully it works in all cases, but it has at least worked in the examples that I've tried it on.

I also found a script that copies my string to the clipboard, which is the function at the end.
If anyone can find an issue with it, please let me know so I can fix it.

Thank you for getting me down the road. I appreciate the help.

Here is my working code:

Sub GetSMTPAddressForAll()
    
    Dim recips As Outlook.Recipients
    Dim recip As Outlook.Recipient
    Dim pa As Outlook.PropertyAccessor
    Dim strR As String
    Dim Response As VbMsgBoxResult
    Dim mail As Outlook.MailItem
        
    Const PR_SMTP_ADDRESS As String = _
        "http://schemas.microsoft.com/mapi/proptag/0x39FE001E"
        
    Set mail = Application.ActiveInspector.CurrentItem

    Set recips = mail.Recipients
    With recips
        For Each recip In recips
            Set pa = recip.PropertyAccessor
            Debug.Print recip.Name & " SMTP=" & pa.GetProperty(PR_SMTP_ADDRESS)
            strR = pa.GetProperty(PR_SMTP_ADDRESS) & "," & strR
        Next
    
    End With
    strR = strR & mail.Sender.PropertyAccessor.GetProperty(PR_SMTP_ADDRESS)
    
    Clipboard (strR)

End Sub


Function Clipboard(Optional StoreText As String) As String
'PURPOSE: Read/Write to Clipboard
'Source: ExcelHero.com (Daniel Ferry)

Dim x As Variant

'Store as variant for 64-bit VBA support
  x = StoreText

'Create HTMLFile Object
  With CreateObject("htmlfile")
    With .parentWindow.clipboardData
      Select Case True
        Case Len(StoreText)
          'Write to the clipboard
            .setData "text", x
        Case Else
          'Read from the clipboard (no variable passed through)
            Clipboard = .GetData("text")
      End Select
    End With
  End With

End Function

 

[Diane Poremsky]

Yeah, if you use exchange, you need to look up the SMTP for internal users.

Or filter them out. This is how I did it when I was testing the macro

     With obj
    ' do whatever
       Debug.Print .Subject, .SenderEmailAddress
  
      Set Recipients = .Recipients
      For i = Recipients.Count To 1 Step -1

      Set R = Recipients.Item(i)
       Debug.Print UCase(R.Address)
    If InStr(1, UCase(R.Address), "/OU") = 0 Then
      strR = R.Address & "; " & strR
    End If

        Next i
 If InStr(1, UCase(.SenderEmailAddress), "/OU") = 0 Then
   strR = .SenderEmailAddress & "; " & strR
 End If
 
     End With

You can also add the string to a new message body.

Set olMsg = Application.CreateItem(olMailItem)
With olMsg
.Subject = Now ' the current time and date
    .BodyFormat = olFormatPlain
    .Body = strR 
    .Display
End With