VBA to Sort Rules [A-Z] - code provided

[Treflip]

Not sure if this is the right place to post this code but I didn't see a macro sharing category. @Mods Feel free to move where appropriate.

For outlook2010 exchange - no admin rights

I just wanted to give back a little to the VBA community and Mrs. Poremsky in particular. I have scavenged from everyone for the better part of a year and would like to give this in return (even if it's only for a particular few).

I know the issue with sorting rules and how it applies to the order in which rules run.

• 95% of my rules organize my inbox - sent from/to put in this folder
• I use stop processing rules- after the rule is run no more rules will run afterwards so the order doesn't effect the other rules

These parameters eliminate people that use rules which depend on the order of other rules to run. I can't help you with this script.

Those that can use this macro will find its usefulness as follows:

• Sort rules alphabetically [A-Z] (of sorts - see the comments in the macro for sort precedence)
• Sort rules to see if there is already a rule for a specific person
• Keep rules organized by the rule name - so multiple rules for a specific name will be grouped together
• Print out rules in debug window
• See how rules can be accessed through vba for more rules programming!

Hopefully others will find this useful and be able to organize their rules better. If you would like to sort Z-A then modify the sort operation (it's a bubble sort!)

Without further adieu:

Sub SortRulesbyAlpha()
' Sort order ! " # $ % & ' ( ) * + , -
'  . / 1 2 3 4 : ; < = > ? @
'  A B C D ^ _ a b c d |
'
  Dim Session As Outlook.NameSpace
  Dim oRules As Outlook.rules
  Dim oRule As Outlook.Rule
 
  Dim varRule() As Variant
  Dim srtTmp As Variant
 
  Dim i As Long
  Dim j As Variant
 
  Set Session = Application.Session
  Set oRules = Session.DefaultStore.GetRules()
 
  On Error Resume Next
 
  ' Allocate space for array
  ReDim varRule(oRules.Count - 1)
 
  ' Save rules to array: Sort by Name
  i = 0
  For Each oRule In oRules
  Debug.Print oRule.Name & " : " & oRule.ExecutionOrder
  varRule(i) = oRule.Name
  i = i + 1
  Next oRule
 
  ' Sort Rule Names A-Z
  i = 0
  For i = LBound(varRule) To UBound(varRule)
  For j = i + 1 To UBound(varRule)
  If varRule(i) > varRule(j) Then
  srtTmp = varRule(j)
  varRule(j) = varRule(i)
  varRule(i) = srtTmp
  End If
  Next j
  Next i
 
  ' Change Execution Order to Reflect Sort Order
  i = 1
  Debug.Print vbCrLf & vbCrLf & "After Sort"
  For Each j In varRule
  Debug.Print oRules.Item(j).Name & " : " & oRules.Item(j).ExecutionOrder
  oRules.Item(j).ExecutionOrder = i
  i = i + 1
  Next j
 
  'Save changes
  oRules.Save
 
End Sub

 

[Diane Poremsky]

Thanks for sharing.

 

[Diane Poremsky]

BTW, this works with Outlook 2010 and up - it might work with Outlook 2007 (did not test it with 2007).

 

[Treflip]

You're welcome! I have 2010 on my work laptop. I haven't tried for earlier...

 

[Diane Poremsky]

I tested it in 2013 and also in a beta build I have - it works perfectly in the newer versions. I'm pretty sure the rules objects it uses were added to the 2007 object but haven't double checked or tested it - and that is what controls what version it will work with. (That's for the benefit of anyone who finds this post and wonders if it will work.)

 

[Nobol]

I may have missed the obvious, but is there anything to change in the code, or should the macro be run in a certain way? Nothing happens when I run it (my Outlook settings do allow macros to be run).

 

[Diane Poremsky]

Go to File, Options, Trust Center - then Macro Settings and set security to low. You'll probably need to restart Outlook... then the macros should work.

 

[Nobol]

This was actually not the issue, my settings were letting me run macros (but it's always better to check twice on these settings; thanks for the prompt feedback).

I found the fix: any rule calling out "stop processing more rules" prevent the macro from running (these also happen to be client-only in my case, but I don't know if that had any impact). Disabling these allowed the macro to run.

A big thanks to Treflip for this macro, this made my day! (now I know there are 2 of us at least using rules in a similar fashion.)

 

[Diane Poremsky]

Thanks for the update. It's interesting that it affected it.

 

[Treflip]

Hello Nobol! I'm glad there's at least 2 of us too!

So if I understand you correctly, you had to remove the 'stop processing more rules' from your rules prior to running this macro or your rules wouldn't sort at all? Is that correct? I am curious about why that affects this macro on your computer. I have that rule for 95% of my macros... I would be interested to see if you added the 'stop processing more rules' rule back to a few rules and jumble the order up a bit and rerun it to see if it still sorts. I would be surprised if it did not run and correctly sort them afterwards. Try it out and let me know if it adding it back still breaks it and I'll look into it further.

-Tre

Thanks for trying it out and providing feedback!