Changing Contact Notes Font

[Joel Schwartz]

I always want my contact notes to use the Segoe UI 10 font. I can set up new contact notes to have that font, but I use Google Apps Sync for Outlook and it always uses Calibri 11 when it updates a contact. Also, whenever I have to recreate a profile, which I recently did, it brings all of my contacts into Outlook with Calibri 11. I've talked to Google about that but they say that can't be controlled, so I'd like to make a macro which will select all text in the contact notes field and set the font to Segoe UI 10. I'm familiar with Excel macro coding but haven't done anything in Outlook before. Can someone show me the VBA code which would select all text in the contact notes area and change the font to Segoe UI 10?

 

[Diane Poremsky]

I have a macro that will get you pointed in the right direction. See http://www.slipstick.com/developer/change-font-outlook-item-notes-field/ - specifically the last one.

Put it together with my 'super duper bulk changer' to run it on the contacts at any time
http://www.slipstick.com/outlook/contacts/bulk-change-outlook-contacts-file-as-format/

 

[Joel Schwartz]

Diane: Thanks for the help. I was able to get the part going where I can easily change the font for whatever contact I'm on with the macro. I wasn't clear on how to do this on all contacts, or a list of contacts, though. But what I have seems to work just fine.

 

[Diane Poremsky]

The last one on the page at http://www.slipstick.com/developer/change-font-outlook-item-notes-field/ should do the selected items. Changing it to all contacts in the default folder means changing the folder:

' or set this for current folder: objContactsFolder = Application.ActiveExplorer.CurrentFolder
Set objContactsFolder = Application.GetDefaultFolder(olFolderContacts)
Set objItems = objContactsFolder.Items
For Each obj in objItems

 

[Joel Schwartz]

Diane: I'd like to revisit this. What I'm looking for is a macro where I can change just the contact note I've selected. What I have tries to change contacts in whatever might have been returned in a search of contacts, not just the one I've selected to view. I'd also like to set the formatting style back to normal, since many times the style has been set to Heading 1 for some reason. Here's the code I'm using, and admittedly I'm not too up on VBA for Outlook, but here goes. Thanks in advance. - Joel

Public Sub Segoe_Font()
' http://slipstick.me/888jf
Dim currentExplorer As Explorer
Dim Selection As Selection
Dim obj As Object

Dim objWord As Word.Application
Dim objDoc As Word.Document
Dim objSel As Word.Selection
On Error Resume Next

Set currentExplorer = Application.ActiveExplorer
Set Selection = currentExplorer.Selection
For Each obj In Selection
Set objItem = obj
objItem.Display

Set objInsp = objItem.GetInspector
Set objDoc = objInsp.WordEditor
Set objWord = objDoc.Application
Set objSel = objWord.Selection
objSel.WholeStory

With objSel.Font
.Name = "Segoe UI"
.Size = 10
' .Color = wdColorGreen
End With
'objItem.Close olSave

Err.Clear
Next
Set currentExplorer = Nothing
Set obj = Nothing
Set Selection = Nothing



End Sub

 

[Diane Poremsky]

That code does the selection -
Replce the top part of the code with the following to work with just the selected item. I'm not sure about changing the style settings, but if it can be done in Word VBA then it will work in Outlook.

Public Sub Segoe_Font()
' http://slipstick.me/888jf
Dim objApp As Outlook.Application
dim objItem as Outlook.contactitem 
Dim objWord As Word.Application
Dim objDoc As Word.Document
Dim objSel As Word.Selection
On Error Resume Next

Set objApp = Application
Set objItem = objApp.ActiveExplorer.Selection.Item(1)
objItem.Display

 

[Joel Schwartz]

Diane: Here's my new code but so far it does nothing. It's executing because I put stops in the code but it doesn't affect anything in the notes while previously it did. I probably missed something:

Public Sub Segoe_Font()
' http://slipstick.me/888jf
Dim objApp As Outlook.Application
Dim objItem As Outlook.ContactItem
Dim objWord As Word.Application
Dim objDoc As Word.Document
Dim objSel As Word.Selection
On Error Resume Next

Set objApp = Application
Set objItem = objApp.ActiveExplorer.Selection.Item(1)
objItem.Display

With objSel.Font
.Name = "Segoe UI"
.Size = 10
End With

Err.Clear

End Sub

 

[Michael Bauer]

Remove the On Error Resume Next, then it will tell you that objSel is Nothing. See Diane's example for where to set the variable.

 

[Joel Schwartz]

Well, this is what I finally came up with to simply change the font in one contact's notes field and set the style to normal. It seems to work, but I have no idea if it's fully properly coded. It just know for now that it works:

Public Sub Segoe_Font()

Dim olInspector As Outlook.Inspector
Dim olDocument As Word.Document
Dim olSelection As Word.Selection

Set olInspector = Application.ActiveInspector()
Set olDocument = olInspector.WordEditor
Set olSelection = olDocument.Application.Selection
olSelection.WholeStory
olSelection.Style = "Normal"

With olSelection.Font
.Name = "Segoe UI"
.Size = 10
End With

Set m_Inspector = Nothing

End Sub

 

[Michael Bauer]

Looks good.