Outlook 2019 Display the output of a seach in a new Window

[Witzker]

How can the result of e.g this search be displayes in a new window in a list with name and Email?

Sub CopyContacts()
  
   Dim ContactsFolder As Outlook.Folder
   Dim DestFolder As Outlook.Folder
   Dim ContactItems As Outlook.Items
   Dim ResItems As Outlook.Items
   Dim sFilter, strCategory As String
   Dim iNumRestricted As Integer
   Dim Item As ContactItem, CopiedItem As ContactItem

' Use the default folder
Set ContactsFolder = Session.GetDefaultFolder(olFolderContacts)

' Use the selected folder
'Set ContactsFolder = Application.ActiveExplorer.CurrentFolder

' copy to subfolder
Set DestFolder = ContactsFolder.Folders("Copies")

   ' Get all of the items in the folder
   Set ContactItems = ContactsFolder.Items
 
   'create the Restrict filter
strCategory = InputBox("Enter the category")

   sFilter = "[Categories] = " & strCategory
   ' Apply the filter to the collection
   Set ResItems = ContactItems.Restrict(sFilter)
   iNumRestricted = 0
   'Loop through the items in the collection.
   For Each Item In ResItems
      iNumRestricted = iNumRestricted + 1

I cannot find the way to schow the result in a list where I can then click the contact to open it
Hope for Suggestions
THX

 

[Diane Poremsky]

From

Search for All Messages from Contact and Display in New Window

Victor Beekman wanted to share another macro with our visitors. This is similar to our macros that search for all messages from a contact or sender but instead of doing an "in-place" search, it opens a new window with the results.

www.slipstick.com

These will open a new window and turn off some of the panes - if I recall correct, the new todobar can't be turned off - that's why I have it commented out. Put it at the end of the macro.

Without testing it, you would replace olkFilter with sFilter from your code -

    Call olkExplorer.Search(olkFilter, olSearchScopeAllOutlookItems)
    Call olkExplorer.Display
' hide the navigation bar & preview pane
    olkExplorer.ShowPane olFolderList, False
    olkExplorer.ShowPane olOutlookBar, False
    olkExplorer.ShowPane olPreview, False
    olkExplorer.ShowPane olNavigationPane, False
    'olkExplorer.ShowPane olToDoBar, False

 

[Diane Poremsky]

It looks like it needs a lot more tweaking than just adding that -to the code.
It was opening a new window but finding mail.

For anyone who finds this this - the original macro is from this thread -

Macro to find contacts by category and copy them to another folder

Hello, I'm having trouble finding the answer to my issue and am hoping for some help. I'm looking for a way to search my contact folder in Outlook for contacts in a certain category and ultimately export just those contacts into an excel workbook or CSV. I figured the code would search...

forums.slipstick.com

This is finding one contact.... but opens in a new window.

Sub CopyContacts()
  
   Dim ContactsFolder As Outlook.folder
   Dim DestFolder As Outlook.folder
   Dim ContactItems As Outlook.Items
   Dim ResItems As Outlook.Items
   Dim sFilter, strCategory As String
   Dim iNumRestricted As Integer
   Dim Item As ContactItem, CopiedItem As ContactItem

' Use the default folder
'Set ContactsFolder = Session.GetDefaultFolder(olFolderContacts)

Dim olkExplorer As Outlook.Explorer
Set olkExplorer = Application.Explorers.Add(Application.Session.GetDefaultFolder(olFolderContacts), olFolderDisplayNormal)

 '  Set ContactItems = ContactsFolder.Items
 
   'create the Restrict filter
strCategory = InputBox("Enter the category")

   sFilter = "[Categories] = " & strCategory
  
  
 Call olkExplorer.Search(sFilter, olSearchScopeSubfolders)
    Call olkExplorer.Display
' hide the navigation bar & preview pane
    olkExplorer.ShowPane olFolderList, False
    olkExplorer.ShowPane olOutlookBar, False
    olkExplorer.ShowPane olPreview, False
    olkExplorer.ShowPane olNavigationPane, False
    'olkExplorer.ShowPane olToDoBar, False
    

   Set Item = Nothing
   Set CopiedItem = Nothing
   Set ResItems = Nothing
   Set ContactItems = Nothing
   Set ContactsFolder = Nothing
 
End Sub

 

[Diane Poremsky]

Sub FindContacts()
  
Dim olkExplorer As Outlook.Explorer
Dim sFilter, strCategory As String

Set olkExplorer = Application.Explorers.Add(Application.Session.GetDefaultFolder(olFolderContacts), olFolderDisplayNormal)
  
   'create the Restrict filter
strCategory = InputBox("Enter the category")
' category:="keyword"
sFilter = "Categories:=""" & strCategory & """"
  
 Call olkExplorer.Search(sFilter, olSearchScopeCurrentFolder)
    Call olkExplorer.Display
' hide the navigation bar & preview pane
    olkExplorer.ShowPane olFolderList, False
    olkExplorer.ShowPane olOutlookBar, False
    olkExplorer.ShowPane olPreview, False
   ' olkExplorer.ShowPane olNavigationPane, False
    'olkExplorer.ShowPane olToDoBar, False
    
   Set olkExplorer = Nothing
 
End Sub

All of the panes are turned off. If the nav pane is turned off, it is turned off when you restart Outlook - at least it is for me.

 

[Witzker]

THX I will check

 

[Witzker]

Worx great THX
the only thing to consider is to use the German field name to work in German version of Outlook
sFilter = "Categories:=""" & strCategory & """"
is
sFilter = "Kategorie:=""" & strCategory & """"

That make Things more difficult
is there a list somewhere with English and German field names?

Categories = Kategorie
and so on

 

[Witzker]

Hi again
I now want to open the search window with a new defined View called "XSearch" that better reflects the necessary fields to open the need contact.

But without losing the current view of the contact folder.
When I close the search window.
Can you pls help with the new code?