Auto forward email that is moves into a specific outlook folder

[richardwing]

Hello I really love this forum.

I am really new to VBA.

I am looking to auto reply and auto forward the same email, each with a custom html body message, when the email arrives into a specific folder.

I located this vba to auto forward emails. but its not folder specific nor does it have the reply functionality either.

Sub ForwardEmail(Item As Outlook.MailItem)
// Determine if it’s an email
If TypeName(Item) = "MailItem" Then
    With Item.Forward
        .Subject = ("ITS - ") & Item.Subject
        .Recipients.Add "backup@email.com"
        .Recipients.Add "backup2@email.com"
        ' You need to overwrite the Body or HTMLBody to get rid of the auto signature
        .HTMLBody = Item.HTMLBody ' <-- Or use .Body for Plain Text
        '.Display ' <-- For Debug
        .Send ' <-- Put break here to Debug
End With
End If
End Sub

Could someone help with this. I am willing to pay as well. Just direct me to the correct place to discus payment.


Lastly, is there a bit of code that I can add to allow any of the vba scripts that I come across that run for inbox items to only run in specific folders?

Thanks for your time and direction.

Richard

 

[Diane Poremsky]

Lastly, is there a bit of code that I can add to allow any of the vba scripts that I come across that run for inbox items to only run in specific folders?

You need to use an itemadd macro for this - it watches the folder and when a new message is added, does whatever.

How to use an ItemAdd Macro

An ItemAdd macro watches a specific folder and runs a macro on it as messages are dropped into it, using any method: using rules, dragging messages to the folder, using the move or copy to folder command, or even copy and paste in place.

www.slipstick.com

Option Explicit
Private objNS As Outlook.NameSpace
Private WithEvents objItems As Outlook.Items

Private Sub Application_Startup()
 
Dim objWatchFolder As Outlook.Folder
Set objNS = Application.GetNamespace("MAPI")

'Set the folder and items to watch:
Set objWatchFolder = objNS.GetDefaultFolder(olFolderInbox)
Set objItems = objWatchFolder.Items

Set objWatchFolder = Nothing
End Sub

Private Sub objItems_ItemAdd(ByVal Item As Object)

' Determine if it’s an email
If TypeName(Item) = "MailItem" Then
    
    With Item.Forward
        .Subject = ("ITS - ") & Item.Subject
        .Recipients.Add "backup@email.com"
        .Recipients.Add "backup2@email.com"
        ' You need to overwrite the Body or HTMLBody to get rid of the auto signature
        .HTMLBody = Item.HTMLBody ' <-- Or use .Body for Plain Text
        .Display ' <-- For Debug
        '.Send ' <-- Put break here to Debug
    End With

    With Item.Reply
        .Body = "Regarding: " & Item.Subject & vbCrLf & _
            "In Reply to: " & Item.Subject & vbCrLf & _
            "More required text" & vbCrLf & vbCrLf & Item.Body 
        .CC = "alias1@domain.com"
        .BCC = "alias2@domain.com"
        .Subject = "subject text- " & Item.Subject
        .Display

    End With
End If
End Sub

 

[richardwing]

You need to use an itemadd macro for this - it watches the folder and when a new message is added, does whatever.

How to use an ItemAdd Macro

An ItemAdd macro watches a specific folder and runs a macro on it as messages are dropped into it, using any method: using rules, dragging messages to the folder, using the move or copy to folder command, or even copy and paste in place.

www.slipstick.com

Option Explicit
Private objNS As Outlook.NameSpace
Private WithEvents objItems As Outlook.Items

Private Sub Application_Startup()
 
Dim objWatchFolder As Outlook.Folder
Set objNS = Application.GetNamespace("MAPI")

'Set the folder and items to watch:
Set objWatchFolder = objNS.GetDefaultFolder(olFolderInbox)
Set objItems = objWatchFolder.Items

Set objWatchFolder = Nothing
End Sub

Private Sub objItems_ItemAdd(ByVal Item As Object)

' Determine if it’s an email
If TypeName(Item) = "MailItem" Then
   
    With Item.Forward
        .Subject = ("ITS - ") & Item.Subject
        .Recipients.Add "backup@email.com"
        .Recipients.Add "backup2@email.com"
        ' You need to overwrite the Body or HTMLBody to get rid of the auto signature
        .HTMLBody = Item.HTMLBody ' <-- Or use .Body for Plain Text
        .Display ' <-- For Debug
        '.Send ' <-- Put break here to Debug
    End With

    With Item.Reply
        .Body = "Regarding: " & Item.Subject & vbCrLf & _
            "In Reply to: " & Item.Subject & vbCrLf & _
            "More required text" & vbCrLf & vbCrLf & Item.Body
        .CC = "alias1@domain.com"
        .BCC = "alias2@domain.com"
        .Subject = "subject text- " & Item.Subject
        .Display

    End With
End If
End Sub

Thank you for the response to my post. I regret to say I am not quite sure where or how I would define the folder or sub folder I would like it to process.

If its not too much trouble could you explain that piece in detail where and how I insert the name of the folder I wish the code to work in.

Thanks in advance.

 

[richardwing]

To set a folder on the same level as the inbox would I switch out the lines like so?

Set objWatchFolder = objNS.GetDefaultFolder(olFolderInbox) 

with

Set objWatchFolder = objNS.GetDefaultFolder("folder1")

To set a subfolder of a folder on the same level as Inbox would I switch out the line like so?

Set objWatchFolder = objNS.GetDefaultFolder(olFolderInbox) 

with

Set objWatchFolder = objNS.GetDefaultFolder("folder1").Folders("fol2")

To set a subfolder of inbox folder would I switch out the line like so?

Set objWatchFolder = objNS.GetDefaultFolder(olFolderInbox) 

with

Set objWatchFolder = objNS.GetDefaultFolder(olFolderInbox).Folders("fol2")

 

[Diane Poremsky]

Same level as inbox:
Set objWatchFolder = objNS.GetDefaultFolder(olFolderInbox).Parent.Folders("Folder name")

Subfolder of folder at same level as inbox
Set objWatchFolder = objNS.GetDefaultFolder(olFolderInbox).Parent.Folders("Folder name").folders("name")
but... you shouldn't use so many dots.

This is better -
Set objParentFolder = objNS.GetDefaultFolder(olFolderInbox).Parent.Folders("Folder name")
Set objWatchFolder = objParentFolder.folders("name")

This is correct for a subfolder of the inbox -
Set objWatchFolder = objNS.GetDefaultFolder(olFolderInbox).Folders("fol2")

If you are using multiple folders, I would do it like this -

Set objInboxFolder = objNS.GetDefaultFolder(olFolderInbox)
Set objParentFolder = objInboxFolder.Parent.Folders("Folder name")
Set objWatchFolder = objParentFolder.folders("name")

Set objParentFolder2 = objInboxFolder.Parent.Folders("Folder name2")
Set objWatchFolder2 = objParentFolder.folders("name2")

Working with VBA and non-default Outlook Folders

How to use VBA to 'do something' in Outlook's non-default folders.

www.slipstick.com

 

[richardwing]

Same level as inbox:
Set objWatchFolder = objNS.GetDefaultFolder(olFolderInbox).Parent.Folders("Folder name")

Subfolder of folder at same level as inbox
Set objWatchFolder = objNS.GetDefaultFolder(olFolderInbox).Parent.Folders("Folder name").folders("name")
but... you shouldn't use so many dots.

This is better -
Set objParentFolder = objNS.GetDefaultFolder(olFolderInbox).Parent.Folders("Folder name")
Set objWatchFolder = objParentFolder.folders("name")

This is correct for a subfolder of the inbox -
Set objWatchFolder = objNS.GetDefaultFolder(olFolderInbox).Folders("fol2")

If you are using multiple folders, I would do it like this -

Set objInboxFolder = objNS.GetDefaultFolder(olFolderInbox)
Set objParentFolder = objInboxFolder.Parent.Folders("Folder name")
Set objWatchFolder = objParentFolder.folders("name")

Set objParentFolder2 = objInboxFolder.Parent.Folders("Folder name2")
Set objWatchFolder2 = objParentFolder.folders("name2")

Working with VBA and non-default Outlook Folders

How to use VBA to 'do something' in Outlook's non-default folders.

www.slipstick.com

Thank you so much.