show the correct calendar on start

[Thorsten]

Hello,

i've found Dianes makro for choosing the calendars in Outlook.
The pc should start with with Wakeonlan and Outlook in autostart and should show the correct calendar in Outlook (Conferenceroom Display). But when i select 'start Outlook with calendar view' it is showing the users calendar and not the one selected with case x. Only if i start the makro manually afterwards or if Outlook is started with emailview and then switched to calendars it is working (but not so automatic as i wish).
Is there a way for complete autostartstart with the (shared) calendar i wanted?

Regards
Thorsten

 

[Thorsten]

Sorry - i've forgot the code:

Dim WithEvents objPane As NavigationPane
   
Private Sub Application_Startup()
  Set objPane = Application.ActiveExplorer.NavigationPane
   
End Sub
   
   
Private Sub objPane_ModuleSwitch(ByVal CurrentModule As NavigationModule)
  Dim objPane As NavigationPane
  Dim objModule As CalendarModule
  Dim objGroup As NavigationGroup
  Dim objNavFolder As NavigationFolder
  Dim objCalendar As Folder
  Dim objFolder As Folder
   
  Dim i As Integer
   
  If CurrentModule.NavigationModuleType = olModuleCalendar Then
  Set Application.ActiveExplorer.CurrentFolder = Session.GetDefaultFolder(olFolderCalendar)
  DoEvents
   
  Set objCalendar = Session.GetDefaultFolder(olFolderCalendar)
  Set objPane = Application.ActiveExplorer.NavigationPane
  Set objModule = objPane.Modules.GetNavigationModule(olModuleCalendar)
   
  With objModule.NavigationGroups
  Set objGroup = .GetDefaultNavigationGroup(olMyFoldersGroup)
 
  ' To use a different group
  ' Set objGroup = .Item("group name")
  End With
 
 
  For i = 1 To objGroup.NavigationFolders.Count
  Set objNavFolder = objGroup.NavigationFolders.Item(i)
  Select Case i
 
  ' Enter the calendar index numbers you want to open
  Case 2
  objNavFolder.IsSelected = True
   
  ' Set to True to open side by side
  objNavFolder.IsSideBySide = False
  Case Else
  objNavFolder.IsSelected = False
  End Select
  Next
  End If
  Set objPane = Nothing
  Set objModule = Nothing
  Set objGroup = Nothing
  Set objNavFolder = Nothing
  Set objCalendar = Nothing
  Set objFolder = Nothing
End Sub

 

[Diane Poremsky]

Because the calendar is the startup folder, you can select the folder in the start up routine- this woks and assumes the calendar you want opened is the second one.

Because its a shared calendar, it doesn't open fast enough to deselect the first calendar (and doevents doesn't slow it down enough) but you might be able to deselect if the calendar you want opened is cached in the profile.

This code opens the second calendar, overlaid and as the in focus calendar.

Private Sub Application_Startup()
  Dim objPane As NavigationPane
  Dim objModule As CalendarModule
  Dim objGroup As NavigationGroup
  Dim objNavFolder As NavigationFolder
 
  Set objPane = Application.ActiveExplorer.NavigationPane
  Set objModule = objPane.Modules.GetNavigationModule(olModuleCalendar)
 
  With objModule.NavigationGroups
  Set objGroup = .GetDefaultNavigationGroup(olMyFoldersGroup)
  End With
On Error Resume Next
Set objNavFolder = objGroup.NavigationFolders.Item(2)
DoEvents
objNavFolder.IsSelected = True
objNavFolder.IsSideBySide = False
DoEvents
Set objNavFolder = objGroup.NavigationFolders.Item(1)
objNavFolder.IsSelected = False

  End Sub

 

[Thorsten]

Because the calendar is the startup folder, you can select the folder in the start up routine- this woks and assumes the calendar you want opened is the second one.

Because its a shared calendar, it doesn't open fast enough to deselect the first calendar (and doevents doesn't slow it down enough) but you might be able to deselect if the calendar you want opened is cached in the profile.

This code opens the second calendar, overlaid and as the in focus calendar.

Private Sub Application_Startup()
  Dim objPane As NavigationPane
  Dim objModule As CalendarModule
  Dim objGroup As NavigationGroup
  Dim objNavFolder As NavigationFolder

  Set objPane = Application.ActiveExplorer.NavigationPane
  Set objModule = objPane.Modules.GetNavigationModule(olModuleCalendar)

  With objModule.NavigationGroups
  Set objGroup = .GetDefaultNavigationGroup(olMyFoldersGroup)
  End With
On Error Resume Next
Set objNavFolder = objGroup.NavigationFolders.Item(2)
DoEvents
objNavFolder.IsSelected = True
objNavFolder.IsSideBySide = False
DoEvents
Set objNavFolder = objGroup.NavigationFolders.Item(1)
objNavFolder.IsSelected = False

  End Sub

Hello Diane,
thats it- thank you.
After activating the Exchange cache mode it works.
So now we have laptops in front of the conference rooms (in a box where only the display is shown), they are starting with wakeonlan, autologin and Outlook in autostart with calendar view of the shared calendar (room resource).
Thank you for help.
Thorsten

 

[Diane Poremsky]

My guess is that it didn't work in online mode because of the delay in loading the shared calendar. You'd need to build in a pause to wait a few seconds for it run the code because Outlook itself does not include a timer.

 

[Thorsten]

It is fine like it is now. Thank you again for quick help.
It was easier before when were allowed to use a normal user account for the conference calendar, but now with the resource room calendar it is also working because of your script.
Thorsten